Quando abro um PDF com visualização, a configuração padrão é uma janela pequena de rolagem contínua. Eu li muitos manuais do usuário e esta não é uma boa maneira de apresentá-los.

Eu tenho uma tela Thunderbolt de 27 “, então prefiro ter o PDF configurado para mostrar o índice, 2 páginas ao mesmo tempo e com zoom reduzido para tela inteira

Não é possível (que eu consegui descobrir) alterar as configurações padrão de Visualização ao abrir um PDF. Anteriormente, eu tinha que escolher 3 itens de menu para definir meu formato de visualização preferido. Em vez disso, fiz um Applescript para fazer isso por mim.

Instalação

Copie / cole o seguinte no Editor Applescript e salve-o (como um script) na pasta ~ / Library / Scripts.

clickMenuItem("Preview", "View", "Table of Contents")
clickMenuItem("Preview", "View", "Two Pages")
clickMenuItem("Preview", "Go", "Down")
clickMenuItem("Preview", "Window", "Zoom")
clickMenuItem("Preview", "Go", "Up")

on clickMenuItem(applicationName, menuBarItem, menuItem)
  try
    tell application applicationName to activate
    tell application "System Events"
      tell process applicationName
        tell menu bar 1
          tell menu bar item menuBarItem
            tell menu menuBarItem
              click menu item menuItem
            end tell
          end tell
        end tell
      end tell
    end tell
    return true
  on error error_message
    return false
  end try
end clickMenuItem

Configuração

No Editor do Applescript> tela Preferências gerais, ative a caixa de seleção ‘Mostrar menu de script na barra de menus’.

Execução

Selecione o script no menu Script na barra de menu System Status (lado direito)

Notas

Fiz o script ser muito genérico para que possa ser usado com qualquer aplicativo / menu. Simplesmente altere as entradas principais do clickMenuItem para chamar o aplicativo e o menu que você deseja

Se o menu que você deseja selecionar for um submenu, você precisará incluir o seguinte no script.

on clickSubMenuItem(applicationName, menuBarItem, menuItem, subMenuItem)
  try
    tell application applicationName to activate
    tell application "System Events"
      tell process applicationName
        tell menu bar 1
          tell menu bar item menuBarItem
            tell menu menuBarItem
              tell menu item menuItem
                tell menu menuItem
                  click menu item subMenuItem
                end tell
              end tell
            end tell
          end tell
        end tell
      end tell
    end tell
    return true
  on error error_message
    return false
  end try
end clickSubMenuItem

Uso de amostra

...
clickMenuItem("Preview", "Go", "Up")
clickSubMenuItem("Preview","Edit","Spelling and Grammer","Show Spelling and Grammer")

Espero que você ache isso tão útil quanto eu.